How to terminate a gfortran program?

AlexBB · 05-04-2014, 10:54 AM

It must be an elementary question. I am trying to run some of simple gfortran programs and one of them requires human input of 3 numbers which it reads. It can do it indefinitely but when I want to stop it I type q and get an error message along with the program termination all right. What is the correct way to do it? Pressing ESC does not help. Thanks.

jdkaye · 05-04-2014, 11:18 AM

Quote:

Originally Posted by AlexBB

It must be an elementary question. I am trying to run some of simple gfortran programs and one of them requires human input of 3 numbers which it reads. It can do it indefinitely but when I want to stop it I type q and get an error message along with the program termination all right. What is the correct way to do it? Pressing ESC does not help. Thanks.

Do you have the source code for this program? If you do then have a look at it and see if you can figure it out or post it here and someone will be able to do it.
jdk

flshope · 05-04-2014, 11:24 AM

Perhaps the simplest way to terminate execution is to type ctrl-c, which simply kills the process.

What I usually do, though, is something like the following:

...
REAL X
...
READ(*,*)X
IF(X .EQ. 0.)STOP
...

where I have used '0.' as the stopping criterion assuming '0.' is never a valid input value. Of course, you would have to pick some other criterion if '0.' is a valid input for your code.

There are more elaboration ways to stop execution, such as displaying a question to the user to ask if she wants to run another case (e.g., enter 'y' or 'n'). I'll write some more code if you aren't sure how to code this. Let me know.

AlexBB · 05-04-2014, 12:03 PM

Yes, I do have the source code. I copied it from a well known website. Had to do a minor correction since it did not compile first. The code is here:

Code:

C AREA OF A TRIANGLE - HERON'S FORMULA
C INPUT - CARD READER UNIT 5, INTEGER INPUT, ONE BLANK CARD FOR END-OF-DATA
C OUTPUT - LINE PRINTER UNIT 6, REAL OUTPUT
C INPUT ERROR DISPAY ERROR MESSAGE ON OUTPUT
  501 FORMAT(3I5)
  601 FORMAT(4H A= ,I5,5H  B= ,I5,5H  C= ,I5,8H  AREA= ,F10.2,12HSQUARE
     * UNITS)
  602 FORMAT(10HNORMAL END)
  603 FORMAT(23HINPUT ERROR, ZERO VALUE)
      INTEGER A,B,C
   10 READ(5,501) A,B,C
      IF(A.EQ.0 .AND. B.EQ.0 .AND. C.EQ.0) GO TO 50
      IF(A.EQ.0 .OR.  B.EQ.0 .OR.  C.EQ.0) GO TO 90
      S = (A + B + C) / 2.0
      AREA = SQRT( S * (S - A) * (S - B) * (S - C))
      WRITE(6,601) A,B,C,AREA
      GO TO 10
   50 WRITE(6,602)
      STOP
   90 WRITE(6,603)
      STOP
      END

I also have a question here. In that FORMAT statement:

Code:

601 FORMAT(4H A= ,I5,5H  B= ,I5,5H  C= ,I5,8H  AREA= ,F10.2,12HSQUARE

Code:

12HSQUARE

"SQUARE" is not separated from the format itself which I believe is 12H. When I tried to separate it and print the code like

Code:

12H SQUARE

it did not work. It would not give the result expected. It would say "not a number." Why?

If I leave it the way it is then the result looks like this, for example: 123.56SQUARE UNITS or something.

Thanks, - Alex

flshope · 05-05-2014, 08:15 AM

To deal with the '12HSQUARE' problem, I suggest the form of the code be:

Code:

  601 FORMAT(4H A= ,I5,5H  B= ,I5,5H  C= ,I5,8H  AREA= ,F10.2,13H SQUARE
     * UNITS)

To terminate execution using the code as written, type

Code:

0,0,0

This works on my machine running Ubuntu and gfortran -- that is, I get normal termination without an error message.

I would observe that the code is mixing integer and real arithmetic, which is not a good practice.

If I were to write this code according to my own tastes, it would be as follows:

Code:

C AREA OF A TRIANGLE - HERON'S FORMULA
C INPUT - CARD READER UNIT 5, INTEGER INPUT, ONE BLANK CARD FOR END-OF-DATA
C OUTPUT - LINE PRINTER UNIT 6, REAL OUTPUT
C INPUT ERROR DISPAY ERROR MESSAGE ON OUTPUT
C 501 FORMAT(3I5)

      IMPLICIT NONE

  601 FORMAT(' A= ',F10.2,'  B= ',F10.2,'  C= ',F10.2,'  AREA= ',F10.2,
     * ' SQUARE UNITS')
  602 FORMAT('NORMAL END')
  603 FORMAT('INPUT ERROR, ZERO VALUE')
      REAL A,B,C,S,AREA
   10 READ(*,*) A,B,C
      IF(A.EQ.0. .AND. B.EQ.0. .AND. C.EQ.0.) GO TO 50
      IF(A.EQ.0. .OR.  B.EQ.0. .OR.  C.EQ.0.) GO TO 90
      S = (A + B + C) / 2.0
      AREA = SQRT( S * (S - A) * (S - B) * (S - C))
      WRITE(6,601) A,B,C,AREA
      GO TO 10
   50 WRITE(6,602)
      STOP
   90 WRITE(6,603)
      STOP
      END

My compiler statement is:

Code:

gfortran -o HERON.x HERON.f

assuming the source code file name is HERON.f.

jpollard · 05-05-2014, 02:31 PM

Try a simple CTRL-d - aka, end of file.

Interactive fortran read statements are/should be "read(unit,fmt,END=<label>)..." format. Thus an end of file causes the program to exit, or carry out other functions (like saving data) before exit.

AlexBB · 05-06-2014, 06:27 AM

Thank you guys, flshope and jpollard. It is quite interesting. - Alex