simple awk question getline

coldy78 · 04-20-2007, 09:14 PM

I am very new to awk and I hope somebody may be able to help me.

I have one large file which I would like to break up based on the contents of another smaller file

The small file small.txt has one field consisting of numbers 5 through to 200

These numbers correspond to a field in another file.

eg small.txt

5.5
7.8
10.3

large.txt

1 2 3 5.5
1 3 1 5.5
1 4 9 5.5
2 3 8 7.8
1 4 7 7.8
1 5 4 10.3
1 4 5 10.3
1 6 4 12.5
2 3 2 12.5
3 3 2 13.9

etc

So I only want the records in large file corresponding to records in small.txt

I tried

test.awk

getline cat < "small.txt"
$4 ~ /cat/ {print > "new.txt"}

awk -f test.awk large.txt

which does not give me what i was hopping for.

Any suggestions?
Thanks

ghostdog74 · 04-20-2007, 09:48 PM

Code:

awk '
   {
     while ( (getline line < "small.txt") > 0 ) {
        if (line == $4 ) { print }    
     }
   close("small.txt") 
   }
' "large.txt"

output:

Code:

#./test.sh
1 2 3 5.5
1 3 1 5.5
1 4 9 5.5
2 3 8 7.8
1 4 7 7.8
1 5 4 10.3
1 4 5 10.3

makyo · 04-20-2007, 11:18 PM

Hi.

Unless you are required to use awk, you can use grep:

Code:

#!/bin/sh

# @(#) s1       Demonstrate grep patterns from a file.

grep -f small.txt large.txt

Which produces:

Code:

cheers, makyo

makyo · 04-20-2007, 11:39 PM

Hi.

As a riff on ghostdog74's awk script -- this reads the strings only once into an associative array. Then as each data line is read, field 4 is checked to see if it has been used as an index string:

Code:

#!/bin/sh

# @(#) a1       Demonstrate reading strings into associative array.

awk '
BEGIN   { while ( ( getline line < "small.txt" ) > 0 ) {
                        seeking[line] = "true"
                        }
                }
                { if ( $4 in seeking ) {
                        print
                        }
                }
' large.txt

Producing:

Code:

cheers, makyo

( edit 1: typo )