Perl basic opening of files

ifeatu · 12-10-2009, 06:24 PM

I want to open a file and perform some "stuff" to it line by line.

Can you help with syntax for opening the file and reading it line by line?

here is the code I have so far:

Code:

open(MYINPUTFILE, "<STDIN>"

$_ = @ARGV

# Do stuff

ghostdog74 · 12-10-2009, 06:38 PM

perldoc perlopentut

chrism01 · 12-10-2009, 06:41 PM

Very basic starting point

Code:

    # Open cfg file
    open( CONFIG_FILE, "<$cfg_file" ) or
            die "Can't open cfg file: $cfg_file: $!\n";

    # Process cfg file records
    while ( defined ( $cfg_rec = <CONFIG_FILE> ) )
    {
        # Remove unwanted chars
        chomp $cfg_rec;                 # newline

        # your code here
    }

    # Close cfg file
    close (CONFIG_FILE) or
            die "Can't close cfg file: $cfg_file: $!\n";

http://perldoc.perl.org/
http://www.perlmonks.org/?node=Tutorials

kbp · 12-10-2009, 06:42 PM

Try:

Code:

my $file = "test.txt";

open(FILEHANDLE, "$file") || die "Could not open $file";

while (<FILEHANDLE>) {

# do stuff

}

close(FILEHANDLE);

<edit>oops... too slow</edit>

cheers

ghostdog74 · 12-10-2009, 06:54 PM

Quote:

Originally Posted by chrism01

Very basic starting point

Code:

    # Process cfg file records
    while ( defined ( $cfg_rec = <CONFIG_FILE> ) )
    {
        # Remove unwanted chars
        chomp $cfg_rec;                 # newline

        # your code here
    }

"defined" is not necessary.

chrism01 · 12-10-2009, 07:15 PM

Perl Cookbook Chap 8

Quote:

The <FH> operator returns undef on error or when end of the file is reached, so use it in loops like this:

while (defined ($line = <DATAFILE>)) {
chomp $line;
$size = length $line;
print "$size\n"; # output size of line
}

ghostdog74 · 12-10-2009, 07:23 PM

Quote:

Originally Posted by chrism01

Perl Cookbook Chap 8

Perl Cookbook Chap 8 also says

Quote:

Because this is a common operation and that's a lot to type, Perl gives it a shorthand notation. This shorthand reads lines into $_ instead of $line. Many other string operations use $_ as a default value to operate on, so this is more useful than it may appear at first:

while (<DATAFILE>) {
chomp;
print length, "\n"; # output size of line
}

chrism01 · 12-10-2009, 07:30 PM

True, but I always use named vars, not $_. I often write substantial sized Perl progs, so I like to have all my vars explicit.
Possibly also due to having done about 9 yrs of C first...

Sergei Steshenko · 12-10-2009, 07:48 PM

Quote:

Originally Posted by ghostdog74

"defined" is not necessary.

It is necessary - you do not want a line consisting of single 0 to return FALSE.

ghostdog74 · 12-10-2009, 07:48 PM

Quote:

Originally Posted by chrism01

True, but I always use named vars, not $_. I often write substantial sized Perl progs, so I like to have all my vars explicit.
Possibly also due to having done about 9 yrs of C first...

Code:

while ( my $namedvar=<DATAFILE> ){
  ....
}

ghostdog74 · 12-10-2009, 07:50 PM

Quote:

Originally Posted by Sergei Steshenko

It is necessary - you do not want a line consisting of single 0 to return FALSE.

how so? example?

Telemachos · 12-11-2009, 06:47 AM

@Ifeatu: The modern norm is to use a three-argument form of open and lexically scoped filehandles (variables declared with my rather than barewords like FILE). You should also always check the return status of open (and close for that matter).

A simple example might look like this:

Code:

#!/usr/bin/env perl
use strict;
use warnings;

my $file = 'example.txt';

open my $file_handle, '<', $file
    or die "Can't open [$file] for reading: $!";

while (my $line = <$file_handle>) {
    print $line;
}

close $file_handle or die "Problem closing [$file]: $!";

You can use autodie to get rid of some of the boilerplate around open and close.

makyo · 12-12-2009, 11:19 AM

Hi.

Code:

#!/usr/bin/env bash

# @(#) s1	Demonstrate running perl script.

echo
set +o nounset
LC_ALL=C ; LANG=C ; export LC_ALL LANG
echo "Environment: LC_ALL = $LC_ALL, LANG = $LANG"
echo "(Versions displayed with local utility \"version\")"
version >/dev/null 2>&1 && version "=o" $(_eat $0 $1) perl
set -o nounset

echo
echo " perl code:"
cat p1

echo
echo " Data file data1:"
cat data1

echo
echo " Results:"
./p1

exit 0

producing:

Code:

% ./s1

Environment: LC_ALL = C, LANG = C
(Versions displayed with local utility "version")
OS, ker|rel, machine: Linux, 2.6.26-2-amd64, x86_64
Distribution        : Debian GNU/Linux 5.0 
GNU bash 3.2.39
perl 5.10.0

 perl code:
#!/usr/bin/perl

# @(#) p1	Demonstrate read, <>, without defined.

use warnings;
use strict;
use feature qw(switch say);
use 5.010;

my ($debug);
$debug = 0;
$debug = 1;

while ( my $line = <DATA> ) {
  print $line;
}

print "\n";
open( my $data, "<", "data1" ) or die " Cannot open file data1.\n";
while ( my $line = <$data> ) {
  print $line;
}

exit(0);

__DATA__

0
one
two
last

 Data file data1:

0
first
second
final

 Results:

0
one
two
last


0
first
second
final

Data includes empty line and "0".

At one time I had always used function defined in such situations. I don't know when the requirement changed (or apparently changed) ... cheers, makyo

Telemachos · 12-12-2009, 08:26 PM

Quote:

Originally Posted by makyo

Data includes empty line and "0".

Well, yes and no. Your DATA section includes lines consisting of "\n" and "0\n". Both of those, of course, come out true in a boolean context. I suppose that the fear is the edge case of a file with 0 and no newline character (which is unusual but can happen). Still, I can't say that it keeps me up nights.

makyo · 12-12-2009, 11:33 PM

Hi.

Quote:

Originally Posted by Telemachos

... I suppose that the fear is the edge case of a file with 0 and no newline character (which is unusual but can happen). ...

Thanks; I agree about newline alone and "0" followed by newline. However, the Programming perl, 3rd, page 81, says:

Both of these while loops still implicitly test for whether the result of the assignment is defined ...

Adding then a "0" with no newline at the end of datafile data2, and running slightly modified versions of the previously posted codes now called s2 and p2:

Code:

#!/usr/bin/env bash

# @(#) s2	Demonstrate running perl script.

echo
set +o nounset
LC_ALL=C ; LANG=C ; export LC_ALL LANG
echo "Environment: LC_ALL = $LC_ALL, LANG = $LANG"
echo "(Versions displayed with local utility \"version\")"
version >/dev/null 2>&1 && version "=o" $(_eat $0 $1) perl
set -o nounset

echo
echo " perl code:"
cat p2

echo
echo " Data file data2:"
cat data2

echo
echo " Results:"
./p2

echo "That was the final line."
exit 0

produces:

Code:

% ./s2

Environment: LC_ALL = C, LANG = C
(Versions displayed with local utility "version")
OS, ker|rel, machine: Linux, 2.6.26-2-amd64, x86_64
Distribution        : Debian GNU/Linux 5.0 
GNU bash 3.2.39
perl 5.10.0

 perl code:
#!/usr/bin/perl

# @(#) p2	Demonstrate read, <>, without defined.

use warnings;
use strict;
use feature qw(switch say);
use 5.010;

my ($debug);
$debug = 0;
$debug = 1;

while ( my $line = <DATA> ) {
  print $line;
}

print "\n";
open( my $data, "<", "data2" ) or die " Cannot open file data1.\n";
while ( my $line = <$data> ) {
  print $line;
}

exit(0);

__DATA__

0
one
two
last

 Data file data2:

0
first
second
final
0
 Results:

0
one
two
last


0
first
second
final
0That was the final line.

So even the odd case seems to be handled without using the function defined explicitly ... cheers, makyo