Joining command in csh

tboss888 · 02-03-2009, 08:09 PM

Hi all. I did a search for this but did not see anything relevant.

I'm trying to join several strings and execute them as a command but csh does not seem to recognize it as a command, anyone know what I'm doing wrong? numone and numtwo will be passed into the script. (I have to use csh because it is a part of an existing script.)

Code:

#!/bin/csh
set file1=file.dat
set file2=file2.dat
set numone=2
set numtwo=10
set partone='sed '
set parttwo=,
set partthree=d' $file1 > $file2
set cmd=`$partone$numone$parttwo$numtwo$partthree`

WHAT I WANT EXECUTED.

Code:

sed '2,10d' file.dat > file2.dat

When I try to run the script, sed complains about syntax.

tboss888 · 02-03-2009, 11:35 PM

Anyone see any mistakes?

colucix · 02-04-2009, 01:54 AM

Here is a working version:

Code:

#!/bin/csh
set file1=file.dat
set file2=file2.dat
set numone=2
set numtwo=10
set partone="sed '"
set parttwo=","
set partthree="d' $file1 > $file2"
set cmd="$partone$numone$parttwo$numtwo$partthree"
eval $cmd

I added some double quotes to embed strings, useful for strings with spaces and single quotes within them. I think the syntax error was the set partthree line, where you had a redirection after a set command. Embedding the whole string in double quotes solves the problem.

tboss888 · 02-04-2009, 03:45 PM

Thanks! That worked like a charm. I have another that isn't working even with the quotes, any ideas?

Code:

#!/bin/csh
set filename=file.dat
set num=10
set partone="more $filename | grep -n 'RUN ("
set parttwo="' | awk -F ':' '{print $1}'"
set numone="$partone$num$parttwo"
eval $numone

WHAT SHOULD BE EXECUTED.

Code:

more file.dat | grep -n 'RUN (10' | awk -F ':' '{print $1}'

colucix · 02-05-2009, 12:26 AM

You have two problems here: the $1 part of the awk command and the brackets {}. To solve the brackets issue (since they have a special meaning in C-shells) you have to put double quotes around the variable name in the eval command:

Code:

eval "$numone"

The $1 part is the more difficult, since in C-shells you cannot escape the dollar sign using a backslash, as you should do in bash. You have to escape it using single quotes, but since the statement contains other quotes, it's difficult to see what to escape and what not. As a workaround I'd split the command in more parts, leaving the $1 alone:

Code:

#!/bin/csh
set filename=file.dat
set num=10
set partone="more $filename | grep -n 'RUN ("
set parttwo="' | awk -F ':' '{print "
set field='$1'
set partthree="}'"
set numone="$partone$num$parttwo$field$partthree"
eval "$numone"

tboss888 · 02-05-2009, 05:19 PM

Quote:

Originally Posted by colucix

You have two problems here: the $1 part of the awk command and the brackets {}. To solve the brackets issue (since they have a special meaning in C-shells) you have to put double quotes around the variable name in the eval command:

Code:

eval "$numone"

The $1 part is the more difficult, since in C-shells you cannot escape the dollar sign using a backslash, as you should do in bash. You have to escape it using single quotes, but since the statement contains other quotes, it's difficult to see what to escape and what not. As a workaround I'd split the command in more parts, leaving the $1 alone:

Code:

#!/bin/csh
set filename=file.dat
set num=10
set partone="more $filename | grep -n 'RUN ("
set parttwo="' | awk -F ':' '{print "
set field='$1'
set partthree="}'"
set numone="$partone$num$parttwo$field$partthree"
eval "$numone"

Thanks again. In order to execute the code I had to change one thing.
I used:

Code:

set numone=`"$partone$num$parttwo$field$partthree"`