a first-timer perl question...

inkedmn · 07-13-2003, 03:07 PM

ok, so i'm toying with perl a bit and i'm writing a little isbn verifier app (something i write in just about every language i learn). basically, it takes a command line argument of an isbn string (like "123-3245-789X", or whatever), and, through a series of computations, determines if the number is valid...

anyway, here's my code at this moment:

Code:

#!/usr/bin/perl -w
use strict;

# perl ISBN verifier - my first perl attempt

my $sum1 = 0;
my $sum2 = 0;

sub isValid {
    my $sum = shift;
    return ($sum % 11 == 0);
}

sub getSums {
    my $isbn = shift;
    $isbn =~ s/[^\dXx]//;
    foreach(split $isbn) {
        if ($_ == "X" || $_ == "x") {
            $sum1 += 10;
        } else {
            $sum1 += $_;
        $sum2 += $sum1;
        }
    }
}

my $num = $ARGV[1] or die "command line args are wrong";
getSums($num);
if (isValid($sum2)) {
    print "Valid\n";
} else {
    print "Invalid\n";
}

and, when i run it, i get this:

Code:

<|inkedmn@skank|~/code/perl/code>% perl practice.pl 12345678X
command line args are wrong at practice.pl line 27.

my major trouble is grabbing the command-line arguments correctly (and i'm not sure if there are type issues), could somebody please tell me what i'm doing wrong?

thanks!

Mathieu · 07-13-2003, 03:44 PM

Change $ARGV[1] to $ARGV[0]

The first argument is located at [0] of the array (@ARGV)

inkedmn · 07-13-2003, 04:56 PM

yeah, found that right after i posted

python's equivalent is sys.argv which includes the name of program file, so [1] would be the first ACTUAL argument.

having some trouble with a couple other things, i'll post here if i can't figure them out

thanks!

TheLinuxDuck · 07-14-2003, 10:03 AM

For a comparative example, here is my "version" of the isbn number validator. (=

Code:

#!/usr/bin/perl
use strict;
use warnings;

# subroutine prototyping allows us to define subs and what
# they are expected to receive (and perl will give an error,
# usually, if it is called incorrectly)
#
sub isValid($);

#  I've started doing this for the main loop of my scripts lately, to
# keep it inside of a block, for variable scoping, so we don't have
# globals.
#
#MAIN
{
  @ARGV or die "Usage:\n\n\t$0 <isbn_number> <...>\n";
  # test as many numbers as they wish to pass in
  #
  for my $isbnNumber(@ARGV) {
    print isValid($isbnNumber) ? "Valid\n" : "Invalid\n";
  }
  exit;
}

# I combined the sum and valid parts
#
sub isValid($)
{
  # double error checking to make sure that the sub gets called
  # correctly
  #
  my($isbn) = shift || die "isValid: expected isbn number, received nothing\n";
  my($sum)  = 0;
  my($digit);

  $isbn =~ s/[^0-9xX]//g;
  length($isbn) == 10 or return 0;

  # instead of split'ing, pull out each char individually w/ substr
  #
  for my $loc(1..10) {
    $digit = substr($isbn,$loc-1,1);
    $sum += ($digit =~ /[Xx]/ ? 10 : $digit) * $loc;
  }

  return ($sum % 11 == 0);
}

Anyway, that's my take. (=

inkedmn · 07-14-2003, 03:25 PM

ok, so i pretty much got it working (i'll post the code when i get home)...