Have sed case sensitive only some part

BudiKusasi · 10-14-2021, 08:46 PM

How do we in searching by regex e.g.

Code:

sed -Ee '/^\s*[0-9]+.+\*FOOBAR=.+\bfoo\b.+\bbar/p'  F

How do we find exact FOOBAR= and any letter case foo and any letter case bar
Thanks much

Turbocapitalist · 10-14-2021, 09:26 PM

I don't think sed is advanced enough to do that, at least not in a tidy manner.

Code:

sed -n -Ee '/^\s*[0-9]+.+\*FOOBAR=.+\b[Ff][Oo][Oo]\b.+\b[Bb][Aa][Rr]/p'  F

However, you can do it easily with Perl or PCRE:

Code:

perl -n -e '/^\s*[0-9]+.+\*FOOBAR=.+(?i)\bfoo\b.+\bbar/ && print' F

grep -h -P -e '^\s*[0-9]+.+\*FOOBAR=.+(?i)\bfoo\b.+\bbar' F

The (?i) turns on case-insensitivity. Leaving off a matching (?-i) means it applies through to the end of the pattern.

See "man perlre" and scroll down to the section on Extended Patterns and the paragraphs with the heading "(?adlupimnsx-imnsx)" and "(?^alupimnsx)"

allend · 10-15-2021, 12:26 AM

Rather than

Code:

sed -Ee '/REGEXP/p'  F

perhaps you want

Code:

sed -En '/REGEXP/p'  F

shruggy · 10-15-2021, 02:32 AM

Would this be OK?

Code:

sed -En '/^\s*[0-9]+.+\*FOOBAR=/s/=.+\bfoo\b.+\bbar/&/Ip'  F

pan64 · 10-15-2021, 03:08 AM

Quote:

Originally Posted by shruggy

Would this be OK?

Code:

sed -En '/^\s*[0-9]+.+\*FOOBAR=/s/=.+\bfoo\b.+\bbar/&/Ip'  F

Just curious, where is this I flag documented?
In the official documentation I could only find:

Code:

I
i

    The I modifier to regular-expression matching is a GNU extension which makes sed match regexp in a case-insensitive manner.

But probably the upcase and lowercase I are different (and somewhere explained).

shruggy · 10-15-2021, 03:38 AM

No, in my experience they're identical (as a flag to the substitute command). The upper-case variant first appeared in GNU sed 3.01 as a modifier to RE address:

Quote:

Originally Posted by NEWS

Sed 3.01
[...]

One new feature has been added: regular expressions may be followed with an "I" directive ("i" was taken [the "i"nsert command]) to indicate that the regexp should be matched in a case-insensitive manner.

Quote:

Originally Posted by ChangeLog

Thu Aug 14 11:30:04 PDT 1997 Ken Pizzini <ken@gnu.org>

compile.c: added case-insensitive modifier ('I') to address and s/// regexps. The s/// case also accepts the more popular 'i' modifier. (The address regexp cannot use 'i' as a modifier, as that conflicts with the use of the 'i'nsert command.)

So the example above could be simplified as

Code:

sed -En '/^\s*[0-9]+.+\*FOOBAR=/{/=.+\bfoo\b.+\bbar/Ip}'  F