[SOLVED] sed stop insert the line after the first occurrence of the pattern

mackowiakp · 10-08-2020, 02:09 PM

Lets take such text file named "/tmp/test":

Code:

yyyy-1
xxxx-2
xxxx-3
zzzz-4
xxxx-5

I want to insert additional line containing "aaaa-6" before first occurrence of line containing string "xxxx" at the beginning of line. But only one time, as I wrote at first occurrence.

For this purpose I want to use the script like this:

Code:

#!/bin/sh

entry="aaaa-6"
sed -i "/^xxxx*/a $entry" /tmp/test

But this script insert after each occurrence of pattern.
Any idea how to stop sed after first occurrence?
Notice that /bin/sh is used (busybox) not bash.

boughtonp · 10-08-2020, 04:35 PM

Sed works on individual lines at a time - if you're to working on multiple lines, a different tool might be a better fit.

However, GNU sed does have -z to treat the line delimiter as nul char instead of newlines; I don't know if Busybox sed has that, but if it does you can combine it with passing 1 to s/// to instruct it to substitute once, like so:

Code:

sed -z 's/\nxxx[^\n]*\n/\nINSERTED\0/1' input-file

The \0 includes the matched text in the replacement, making this a prepend operation. (Swap places with \0 and \n to make it an append instead.)

If the -z flag isn't available, but using other tools is an option, awk can easily use a flag as part of its condition:

Code:

awk '/^xxx/ && !ins {print "INSERTED";ins=1};{print}' input-file

(To make that an append rather than a prepend, move the final {print} action to the start.)

berndbausch · 10-08-2020, 09:46 PM

Quote:

Originally Posted by mackowiakp

Code:

#!/bin/sh

entry="aaaa-6"
sed -i "/^xxxx*/a $entry" /tmp/test

But this script insert after each occurrence of pattern.
Any idea how to stop sed after first occurrence?

The "a" in the sed command means "append". There is an "i" command, which inserts before a line.

I am not sure if sed can be asked to perform the insertion only at the first occurrence of the line pattern. Check the sed manual (link in my signature).

syg00 · 10-08-2020, 10:48 PM

Normally one would simply use q to stop after a sed sub-command. Doesn't work here because:
- the append consumes everything as its text - including the " ; q}". Didn't know that until I just tested.
- even if it did work, the quit will truncate the file due to the use of "-i".

The only way I could get it done was to read the entire file into the pattern space and change only the first occurrence which sed supports (i.e. don't use append at all).

mackowiakp · 10-09-2020, 01:25 AM

Quote:

Originally Posted by berndbausch

The "a" in the sed command means "append". There is an "i" command, which inserts before a line.

I am not sure if sed can be asked to perform the insertion only at the first occurrence of the line pattern. Check the sed manual (link in my signature).

Yep. a stands for append, i stands for insert. But the output result is the same in both cases.

pan64 · 10-09-2020, 02:26 AM

something like this?:

Code:

sed '/pattern/{a something;q}'

mackowiakp · 10-09-2020, 03:51 AM

Quote:

Originally Posted by pan64

something like this?:

Code:

sed '/pattern/{a something;q}'

My code:

Code:

#!/bin/sh

entry="aaaa-6"
sed "/^xxxx*/{a $entry;q}" /tmp/test

Returns :

Code:

sed: unterminated {

double quote because variable is used inside sed arguments.

syg00 · 10-09-2020, 03:52 AM

See my prior post.

MadeInGermany · 10-09-2020, 04:49 AM

You can read the remainder of the file, so the condition is not hit again.
As multi-lined portable sed code:

Code:

#!/bin/sh
entry="aaaa-6"
sed '
/^xxxx/{
s/$/\
'"$entry"'/
:L
$!N
$!bL
}
' input-file

For some reason an a command turns into an i command when lines are added with N. So I emulated the a command by an s command.

mackowiakp · 10-09-2020, 10:53 AM

Yep @MadeInGermany. WORKS !. But...it place $entry after the first line match, not before. Any modification?

MadeInGermany · 10-09-2020, 01:13 PM

Changed s command to emulate an i command

Code:

sed '
/^xxxx/{
s/^/'"$entry"'\
/
:L
$!N
$!bL
}
' input-file

mackowiakp · 10-09-2020, 02:14 PM

THX! WORKS as expected !

shruggy · 12-27-2021, 01:45 PM

GNU sed knows some useful tricks like the 0 address:

Code:

sed -e "0,/xxxx/{//i$entry" -e\} input-file

Considering the file is being edited in place, I'd rather use ed or vi/ex here. See Exercise 2.2 in Zintz' tutorial.

Code:

vim -es +"0/xxxx/s/^/$entry\r/|x" input-file

I believe most distros symlink ex to vi, so that ex -s would be the same as vim -es above.

You cannot make a one-liner with ed, but a HERE document looks simple and clean:

Code:

<<! ed -s input-file
/xxxx/i
$entry
.
wq
!