[SOLVED] split line after first space

pedropt · 02-02-2018, 12:08 PM

This one i will never get there in this life to figure it out , but dor some here it could be a piece of cake because they problably do scrits all day .

Here it is the thing .

by default , to split a text i use tr command like this :

Quote:

tr " " "\n"<infile >outfile

but this command will not work if i have a file like this :

Quote:

http://balaldhfhkffefef my data something http://ghsdghsdk studd orogg

what i need in this case on the output , is something like this :

Quote:

http://balaldhfhkffefef
my data something
http://ghsdghsdk
studd orogg
etc....

I need tr or any other tool to look into the line , split after first space to a new line , and then look for the splited line , get the other url in another line and etc ....

Is this even possible ?
i know it is , but it will probably a command with 500 letters .

MadeInGermany · 02-02-2018, 12:53 PM

With a standard sed the following should work

Code:

sed '
  s#$# #
  s#\(https\{0,1\}://[^[:space:]]*\)[[:space:]]#\1\
#g
  s# $##
' < infile > outfile

Note that a standard sed uses a backslash followed by a newline in order to print a newline. GNU sed also takes \n for that.
--
Hmm, something is still missing...

pedropt · 02-02-2018, 01:06 PM

Thanks for the output on this one .
It only works for the 1st line .

the output generated on that command using the text i provided is :

Quote:

http://balaldhfhkffefef
my data something http://ghsdghsdk
studd orogg

keefaz · 02-02-2018, 02:29 PM

Using 2 passes:

Code:

sed -re 's| ?(https?://[^ ]*) |\n\1\n|g' -e 's/^\n//' infile > outfile

pedropt · 02-02-2018, 04:30 PM

Worked like a charm , i was hopping to be much more complicated this process .
Nice work and thank you for your contribution .

MadeInGermany · 02-04-2018, 11:35 AM

For symmetry reason, and indeed covering a line that ends with a URL:

Code:

sed -r 's| ?(https?://[^ ]*) ?|\n\1\n|g; s/^\n//; s/\n$//'

danielbmartin · 02-04-2018, 11:47 AM

For sake of variety, this is an awk solution.

With this InFile ...

Code:

http://fruit apple banana cherry http://colors red blue  
http://cars honda toyota http://flavors chocolate vanilla 
http://seasons summer fall winter spring

... this awk ...

Code:

awk 'BEGIN{RS="http"} 
  {if (NR>1) {print RS$1; $1="";
              print substr($0,2)}}'  \
$InFile >$OutFile

... produced this OutFile ...

Code:

http://fruit
apple banana cherry
http://colors
red blue
http://cars
honda toyota
http://flavors
chocolate vanilla
http://seasons
summer fall winter spring

Daniel B. Martin

.

danielbmartin · 02-05-2018, 09:14 PM

Another sed solution ...

With this InFile ...

Code:

http://fruit apple banana cherry http://colors red blue  
http://cars honda toyota http://flavors chocolate vanilla 
http://seasons summer fall winter spring

... this code produced ...

Code:

sed 's/ http/\nhttp/g' $InFile |sed 's/ /\n/' >$OutFile

... produced this OutFile ...

Code:

http://fruit
apple banana cherry
http://colors
red blue
http://cars
honda toyota
http://flavors
chocolate vanilla
http://seasons
summer fall winter spring

Daniel B. Martin

.