[SOLVED] Perl: Uninitialized value in pack

CoderMan · 12-21-2009, 01:33 PM

Hi. I'm trying to use the LEGO::NXT modules to control my NXT bot (over bluetooth). I installed just last week with CPAN. But my first run of the example program fails:

Code:

choward@adler /scratch/choward/robots/nxt $ ./test.pl 
Use of uninitialized value in pack at /usr/lib/perl5/site_perl/5.8.8/LEGO/NXT.pm line 498.
Can't call method "type" without a package or object reference at /usr/lib/perl5/site_perl/5.8.8/LEGO/NXT.pm line 1442.

Here is the sample program:

Code:

#!/usr/bin/env perl                                                                                                                                    

use LEGO::NXT;

         # Create a new Bluetooth/NXT object by connecting to                                                                                          
         # a specific bluetooth address and channel.                                                                                                   
my $nxt = LEGO::NXT->new( '00:67:22:AB:32:98', 1 );

$nxt->play_sound_file($NXT_NORET, 0,'! Attention.rso');

$res  = $nxt->get_battery_level($NXT_RET);

         # Turn on Motor 1 to full power.                                                                                                              
         $res = $nxt->set_output_state(
             $NXT_RET,
             $NXT_SENSOR1,
             100,
             $NXT_MOTORON|$NXT_REGULATED,
             $NXT_REGULATION_MODE_MOTOR_SPEED, 0,
             $NXT_MOTOR_RUN_STATE_RUNNING, 0,
    );

Here is the first offending function. Line 498 is the "my $ret = $this->_do_cmd(" line.

Code:

sub play_sound_file
{
  my ($this,$needsret,$repeat,$file) = @_;
  my $strlen = 1+length($file);
  my $ret    = $this->_do_cmd(
    pack("CCCZ[$strlen]",$needsret,$NXT_PLAY_SOUND_FILE,$repeat,$file),
    $needsret
  );

  return if $needsret==$NXT_NORET;

  $this->_parse_generic_ret($ret);
}

Here is the second. The offending line is "if ($comm->type eq 'usb')"

Code:

sub _do_cmd
{
  my ($this,$msg,$needsret) = @_;

  my $comm = $this->{comm};
  my $res;

  if ($comm->type eq 'usb')
  {
    $res = $comm->do_cmd( $msg, $needsret );

    #parsing functions expect prepended length bytes ala bluetooth                                                                                     
    if (defined $res )
    {
      $res = pack('v',length($res)).$res;
    }
  }

  if ($comm->type eq 'blue')
  {
    #bluetooth comm requires prepended length bytes                                                                                                    
    $res = $comm->do_cmd( pack( "v", length($msg) ) . $msg, $needsret );
  }

  $res;
}

My Perl is a little rusty, and I can't even remember what a pack is. Could somebody point me in the right direction?

[Edit: It is version 2.00 of the library... sample program was taken from the MAN pages installed by CPAN.]

GooseYArd · 12-21-2009, 02:17 PM

Quote:

Originally Posted by CoderMan

Here is the second. The offending line is "if ($comm->type eq 'usb')"

Weird- the example clearly shows passing a string as the first argument to the constructor, but looking at new() itself, it looks like it expects you to pass it an instance, i.e:

Code:

 $nxt = LEGO::NXT->new( new LEGO::NXT:BlueComm('xx:xx:xx:xx',0));                                                                        
  
or
                                                    
  $nxt = LEGO::NXT->new( new LEGO::NXT:USBComm() );

The error message (the second one is the fatal one) means that the program is trying to call a method on a scalar that is not an object, which the string you're passing it now isn't.

Give it another whirl using one of those examples.

.andy

CoderMan · 12-21-2009, 06:55 PM

Okay, I think I figured it out (seems to be working now). I think this is a case of documentation being out of sync with code. Part of the problem was what you described: The tutorial code did not properly describe how to create the object. Another part of the problem was that the tutorial code had mis-spelled some of the constants. Another part of the problem was that (strangely enough) it seems that it is also necessary in the test script to include (excuse me, "use") the LEGO::NXT::BlueComm and LEGO::NXT::Constants packages.

Here was the script that finally connected and did the job:

Code:

#!/usr/bin/env perl                                                                                                                                    

use LEGO::NXT;
use LEGO::NXT::BlueComm;
use LEGO::NXT::Constants;

$nxt = LEGO::NXT->new( new LEGO::NXT::BlueComm('00:67:22:AB:32:98',1));
$nxt->play_sound_file($NXT_NORET, 0,'! Attention.rso');

$res  = $nxt->get_battery_level($NXT_RET);

         # Turn on Motor 1 to full power.                                                                                                              
         $res = $nxt->set_output_state(
             $NXT_RET,
             $NXT_SENSOR_1,
             100,
             $NXT_MOTOR_ON|$NXT_REGULATED,
             $NXT_REGULATION_MODE_MOTOR_SPEED, 0,
             $NXT_MOTOR_RUN_STATE_RUNNING, 0,
    );