matching numbers with nawk

dazdaz · 05-11-2011, 10:17 AM

Hi

I am struggling to understand why nawk matches values that are either 1 or 2 digits in length, but not 100 (3 digits). Am I missing something obvious ? Should I use substr to remove the % ?
I am sure it's something to do with character and string matching behaviour with nawk.

Code:

$ echo "/dev/vx/dsk/dg/volume 4194304 4194304       0   99%    /opt/mountpoint" | nawk '{if ( $5 >= 99 ) {printf "%s\n", $0}}'
        /dev/vx/dsk/dg/volume 4194304 4194304       0   99%    /opt/mountpoint


$ echo "/dev/vx/dsk/dg/volume 4194304 4194304       0   100%    /opt/mountpont" | nawk '{if ( $5 >= 99 ) {printf "%s\n", $0}}'
$

Would appreciate any input.

David the H. · 05-11-2011, 11:53 AM

I remember seeing something like this before. Yes, I believe the % sign makes awk treat it as a string comparison. You'll have to remove it before it will compare them numerically.

dazdaz · 05-11-2011, 02:33 PM

So I need to use gsub to strip out the % from field 5 ? Unfortunately I am not entirely sure of the correct syntax to do this. I've tried a few variations.

Code:

echo "/dev/vx/dsk/dg/volume 4194304 4194304       0   100%    /opt/mountpont" | awk '{num = gsub(/%/, "",$5); if ($num >= 99 ) {printf "%s\n", $0}}'

grail · 05-11-2011, 10:26 PM

Depending on if you wish to do more with num than this comparison, you could just use gensub in the comparison:

Code:

awk 'gensub(/%/,//,"g",$5) >= 99' file

dazdaz · 05-12-2011, 12:11 PM

Hi Grail,

I tried the following using gensub, however it does'nt seem to work as expected, i.e. it does'nt work with 3 digits.

Code:

echo "/dev/vx/dsk/dg/volume 4194304 4194304       0   100%    /opt/mountpont" | awk '{if ( gensub(/%/,//,"g",$5) >= 99 ) {printf "%s\n", $0}}'

What is even stranger is that the % is not stripped out

Code:

echo "/dev/vx/dsk/dg/volume 4194304 4194304       0   101%    /opt/mountpont" | awk 'gensub(/%/,//,"g",$5)'
/dev/vx/dsk/dg/volume 4194304 4194304       0   101%    /opt/mountpont

grail · 05-13-2011, 01:39 AM

Yeah that would be my bad on 2 accounts

1. the second lot of // should be ""
2. gensub is returning a string

Try:

Code:

echo "/dev/vx/dsk/dg/volume 4194304 4194304       0   100%    /opt/mountpont" | awk 'int(gensub(/%/,//,"g",$5)) >= 99'

David the H. · 05-13-2011, 07:57 AM

If you'd rather use sub or gsub you should copy the contents of the field into a variable and manipulate that instead.

Code:

awk '{ x=$5 ; gsub( /%/ , "" , x ) ; if ( x >= 99 ) { printf "%s\n" , $0 } }'

Unlike gensub, sub/gsub directly alter the input string, so using a copy of the field keeps the original safe and sound.

http://www.gnu.org/software/gawk/man...ring-Functions

There may of course be some subtle differences between gawk and nawk, but I don't have nawk available to test.

dazdaz · 05-13-2011, 09:35 AM

Thanks for all the reply's. For some reason I prefer the gsub method, by assigning the value to a variable and then manipulating that.

Nominal Animal · 05-13-2011, 12:11 PM

Quote:

Originally Posted by dazdaz

I am struggling to understand why nawk matches values that are either 1 or 2 digits in length, but not 100 (3 digits).

Explicitly convert the field to a number first, int($1) if it must be an integer, or (1.0*$1) for real numbers. Note that you must keep the parenthesis in the latter one, otherwise it will not work.

In your case,

Code:

nawk '{ if ( (1.0*$5) >= 99 ) printf "%s\n", $0 }'

should work fine. I find this much simpler than filtering the field with regular expressions.

David the H. · 05-14-2011, 01:46 PM

Thank you, NA. That's interesting. I didn't know you could do arithmetic operations on fields containing non-numeric characters. Convenient.

I see that it only works properly if the field starts with an number, however, and it only operates on the initial number string. So a field containing "10foo20" will be treated as "10", and "foo10foo20" will be seen as "0".