Multiline Text Replacement Script

sjreilly · 04-25-2008, 07:19 AM

Hi,

I have a large number of files that contain data in a specific format;

cdfId->simInfo->test1 = '(nil
instParameters (m ne plug tvolt volt)
otherParameters (model)
)

cdfId->simInfo->test2 = '(nil
instParameters (m ne plug tvolt volt)
otherParameters (model)
)

cdfId->simInfo->test3 = '(nil
instParameters (m es ne plug tvolt tunique)
netlistProcedure new
)

I want to modify each file to add an extra term into the instParameters line BUT only on the lines preceded by cdfId->simInfo->test2
So that it looks like;

cdfId->simInfo->test1 = '(nil
instParameters (m ne plug tvolt volt)
otherParameters (model)
)

cdfId->simInfo->test2 = '(nil
instParameters (m ne plug tvolt volt extraterm)
otherParameters (model)
)

cdfId->simInfo->test3 = '(nil
instParameters (m es ne plug tvolt tunique)
netlistProcedure new
)

Any ideas?

TIA

Steve

colucix · 04-25-2008, 07:51 AM

It is not clear to me if the line containing instParameters have to be immediately preceded by cdfId->simInfo->test2. I guess you mean it should be under the cdfId->simInfo->test2 section. In this case you can do something like this in awk:

Code:

/cdfId->simInfo->test2/ { 

# while not encounter instParameters print line and get next line
while ( $1 != "instParameters" ) {
   print
   getline
}

# line found: add extraterm before closing parenthesis
print substr($0,1,index($0,")")-1),"extraterm)"

# go to next line
getline

}

# print any other line not under "cdfId->simInfo->test2" section
1

sjreilly · 04-25-2008, 08:04 AM

colucix,

Sorry for the confusion - (I've now corrected the original). Yes, instParameters should appear on the line below cdfId->simInfo->test2

How would you run awk with your code?

Steve

pixellany · 04-25-2008, 08:17 AM

With SED:

sed '/cdfId->simInfo->test2/{n; s/)$/ extraterm)/}'

Translation:
find a line containing the pattern "cdfId->simInfo->test2"
get the next line
replace the ")" at the end of the line with " extraterm)"

colucix · 04-25-2008, 08:21 AM

Ok. In that case we don't need the while loop, just check if the line below cdfId->simInfo->test2 starts with instParameters:

Code:

/cdfId->simInfo->test2/ {

# print this line and get the next one
print
getline

# if it contains instParameters add extraterm before closing parenthesis
if ( $1 == "instParameters" )
   print substr($0,1,index($0,")")-1),"extraterm)"
else
   print

# go to next line
getline

}

# print any other line not under "cdfId->simInfo->test2" section
1

To run the awk code, save it in a file (for example extraterm.awk) and run the following command

Code:

gawk -f extraterm.awk file

where file is the file to be processed. Unfortunately awk cannot edit the file in place, so you have to redirect the output to a temporary file and then overwrite the original one:

Code:

gawk -f extraterm.awk file > tmpfile
mv tmpfile file

but do this only when you have tested the code over a number of files, until you're satisfied with the result.

colucix · 04-25-2008, 08:23 AM

Quote:

Originally Posted by pixellany

With SED:

sed '/cdfId->simInfo->test2/{n; s/)$/ extraterm)/}'

I was sure that some sed guru would have built a one-line command. Nice one, pixellany!

ischi · 04-25-2008, 09:34 AM

I really need to work on my sed skills ... i love wht it can do but im just to slow to figure out how ...

pixellany · 04-25-2008, 09:50 AM

Quote:

Originally Posted by ischi

I really need to work on my sed skills ... i love wht it can do but im just to slow to figure out how ...

http://www.grymoire.com/Unix/Sed.html

sjreilly · 04-28-2008, 04:02 AM

Brilliant!
Many, many thanks!

Steve