finding the length of an array in perl

acid_kewpie · 09-25-2002, 08:42 AM

i'm currently going totally nuts about this stupid datatype i'm trying to use. i'm so so so sure that the data is being put into the nested arrays properly, as i can instantly recall it on assignment, and pull certain values out using hardcoded array references, BUT the array's length is always being reported back as 1, using "$#array" + 1 "or scalar @array". i'm at a complete loss right now...

Code:

 for my $this_vts (1..$dvd->{vts}[0])
  {
    $dvd->{vts}[$this_vts]=[];
    open (IFO, "ifo_dump $DVD_DEVICE $this_vts 2> /dev/null |") or die "error running ifo_dump! maybe it's not on your path?\n";
    IFO: while (<IFO>)
    {
      if ($_=~/Program \(PGC\): *(\d*)/) {$this_ttn=$1; $dvd->{vts}[$this_vts][$this_ttn]=[]}
      elsif ($_=~/Playback time: (\d\d:\d\d:\d\d)/) {$dvd->{vts}[$this_vts][$this_ttn][0]=$1}
      elsif ($_=~/Cell:\s+(\d+)\s+(\d\d:\d\d:\d\d)/) {$dvd->{vts}[$this_vts][$this_ttn][$1]=$2; print $1, $2, "\n";}
      elsif ($_=~/Menu PGCI Unit table/) {last IFO;}
    }
  }

right, that is where the values become assigned, inparticular the highlighted line, which also includes print lines, which DO print the data i expect.

but it's when i come to interogate the data later with:

Code:

sub show_dvd ($)
{
  my $dvd = shift;
  for my $this_track (1..$dvd->{track}[0])
  {
    my $this_ttn = $dvd->{track}[$this_track]{ttn};
    my $this_vts = $dvd->{track}[$this_track]{vts};
    print scalar $dvd->{vts}[$this_vts][$this_ttn];
    print "NO. $this_track, VTS $this_vts, TTN $this_ttn, LEN $dvd->{vts}[$this_vts][$this_ttn][0], $dvd->{vts}[$this_vts][$this_ttn][1]\n";
  }
}

now, the second print statement DOES print the data in those given positions IF it exists, if not, it will complain about an unitialiased value, which is fair enough. But the first statement, or any permutation i can think of it (e.g. assign the scalar to a $ and then print it later) will always return 1.... always. nryagg!

TheLinuxDuck · 09-25-2002, 10:09 AM

So, $dvd->{vts}[$this_vts][$this_ttn] is an array reference, correct?

If so, you'll need to put @{} around it when using scalar to determine it's length:

Code:

sub show_dvd ($)
{
  my $dvd = shift;
  for my $this_track (1..$dvd->{track}[0])
  {
    my $this_ttn = $dvd->{track}[$this_track]{ttn};
    my $this_vts = $dvd->{track}[$this_track]{vts};
    print scalar @{$dvd->{vts}[$this_vts][$this_ttn]};
    print "NO. $this_track, VTS $this_vts, TTN $this_ttn, LEN $dvd->{vts}[$this_vts][$this_ttn][0], $dvd->{vts}[$this_vts][$this_ttn][1]\n";
  }
}

That should do the trick.

acid_kewpie · 09-25-2002, 10:22 AM

once again you save me!

perfect. spot on, thanks. I know all the documentation is out there, but the problems i'm falling over all seem so hard to describe, let alone search for general information... brilliant, well that saves creating even more variables... super.

TheLinuxDuck · 09-25-2002, 10:36 AM

(= I'm just glad to be of help.. when I first started reading this thread, I didn't think I'd be able to help.

But, the only reason I knew this was because I have struggled with this same thing before. References can be tricky... but, you've got a really good grasp on it.. I'm impressed with how quickly you've taken to perl.

acid_kewpie · 09-25-2002, 10:39 AM

well i've got a degree in computer engineering, once you know one langauge you know half of all the others... you just learn what you should be able to demand and do and find out how to do it. Onl real exceptions i've found are functional languages like ML, which did make my head spin...

TheLinuxDuck · 09-25-2002, 10:50 AM

ML.. hehe.. yea.. there are a few that I don't want to get near, ML is one, and lisp/scheme is another.. I'm sure there are many more, but I'll stick with perl/c/python/java thank you very much. (=