Change nth occurence in every line

ufmale · 10-22-2017, 11:08 PM

I am trying to change every 4th occurence of "," in every line to ":" using vi. Anyone can suggest a solution. I search through the Internet, but couldn't find the right answer.

Turbocapitalist · 10-22-2017, 11:23 PM

Your pattern would be in the form of

Code:

%s/old/new/

with a lot of parenthesis.

syg00 · 10-22-2017, 11:35 PM

Use sed.

KenJackson · 10-25-2017, 10:08 AM

More specifically, something like this:

Code:

sed 's/^\([^,]*,[^,]*,[^,]*,[^,]*\),\(.*\)$/\1:\2/' infile.txt > outfile.txt

or

Code:

sed -i 's/^\([^,]*,[^,]*,[^,]*,[^,]*\),\(.*\)$/\1:\2/' inoutfile.txt

[^,] matches any character but a comma.
\1 matches the contents of the first parentheses.

MadeInGermany · 10-25-2017, 10:30 AM

Indeed a brain teaser.
One comma that can be followed by some non-comma stuff, repeat 3 times (i.e. enclose in \( \) followed by \{3\}), and finally the comma that needs to be substituted.
What matches but needs to be kept is captured in another \( \) that is put back with \1
All that to be repeated until the end of the line.

Code:

sed -i 's/\(\(,[^,]*\)\{3\}\),/\1:/g' file

and in vi/vim

Code:

:%s/\(\(,[^,]*\)\{3\}\),/\1:/g

KenJackson · 10-25-2017, 10:51 AM

Ah! "every" 4th occurrence. I missed that word. Very good, MadeInGermany.

danielbmartin · 10-25-2017, 11:27 AM

Quote:

Originally Posted by ufmale

I am trying to change every 4th occurence of "," in every line to ":" using vi. Anyone can suggest a solution. I search through the Internet, but couldn't find the right answer.

Do a Google search on ...
replace every nth occurrence
... and find this ...
https://arstechnica.com/civis/viewtopic.php?t=370486
... which contains this ...
sed -e's/\(\([^;]*;\)\{8\}[^;]*\);/\1\n/g' nth.txt

Daniel B. Martin

MadeInGermany · 10-25-2017, 02:12 PM

This solution works as well, but can be optimized.
The -e option does not do anything because sed's first argument is always a script.
The very first [^;]* does not contribute and denotes a trailing [^;]*
It is more efficient to start with the ;

Code:

sed 's/\(\(;[^;]*\)\{8\}\);/\1\n/g' nth.txt

And now it is quite like my solution.

danielbmartin · 10-25-2017, 02:31 PM

Quote:

Originally Posted by MadeInGermany

...And now it is quite like my solution.

Yes. Post #7 was not intended as a criticism or correction of your excellent solution. The purpose was to show the OP that a Google search led to a workable solution.

Daniel B. Martin

syg00 · 10-25-2017, 05:10 PM

Code:

sed 's/,/;/4' some.file

Simple is good.

KenJackson · 10-25-2017, 07:15 PM

Quote:

Originally Posted by syg00

Code:

sed 's/,/;/4' some.file

Cool! I use sed a lot, but I didn't know about the number flag. Though I think that will only change the fourth comma, not every fourth comma.

syg00 · 10-25-2017, 07:20 PM

True - that nuance in the requirements evaded me. I shall retreat under my rock.

danielbmartin · 10-25-2017, 07:25 PM

Quote:

Originally Posted by syg00

Simple is good.

Simple is good but this solution fails for strings with 8 or more commas. See post #6.

Daniel B. Martin