[SOLVED] Find and replace in one file with contents in a separate file

xmrkite · 09-03-2015, 04:15 PM

I am working with Volusion and want to change categories for products using libreoffice or by using bash as my info is in csv files. The problem is that my products download file shows categories only by id number (ie. 1, 2, 3, 4)

But I can download a separate categories file that has the id's in one column and the category name in another column.

I want to change the category id's in one file with the actual category name by using the data from the second file.

Here's an example:

---Product File---

Widget1 $19.95 1,3,5 ---Item is in 3 categories

Widget2 $24.95 2,4 ---this means it's in 2 categories

---Category File---

1 Books

2 Watches

3 Desks

4 Chairs

5 Doors

Hopefully this is possible to have my products file show up like this:

Widget1 $19.95 1,3,5 Books,Desks,Doors

Widget2 $24.95 2,4 Watches,Chairs

Is this even possible using libreoffice? If not, could I do this find and replace idea with a simple bash script?

I have 11,000 items and 1200 categories. This will save me a lot of time.

syg00 · 09-03-2015, 08:07 PM

This seems to be a common sort of request - nothing in the "Similar threads" below ?.

Logic should be pretty straightforward - read the category file into an array, then use the numbers in the products records to index into the arrays and append the value. Personally I'd use awk.

Aia · 09-03-2015, 08:42 PM

Please, try this and see if it does what you want.

Code:

awk '
FNR==NR {
    cat[$1]=$2
    next
}
{
    n=split($3, t, ",")
    s=cat[t[1]]
    for(i=2; i<=n; i++)
        s=s "," cat[t[i]]
    print $0, s
}' category.file product.file

Code:

Widget1 $19.95 1,3,5 Books,Desks,Doors
Widget2 $24.95 2,4 Watches,Chairs

xmrkite · 09-04-2015, 04:39 PM

Hey, that got me to it. Thanks