Awk to convert bytes to human number?

Xeratul · 10-20-2011, 04:21 PM

Hello,

I would like to find a program that could convert bytes to something readable mb, gb...

Here a line that is too difficult to read, and to be converted to human size:
received_bytes=1452360394 transmitted_bytes=3135845922

Awk is extremely flexible + very universal. Present almost on any distros.

With google I have not found such a code for awk. Maybe you've got that alreay?

Thank you in advance.

anomie · 10-20-2011, 05:00 PM

Is simple division OK? For instance:

Code:

$ echo '1452360394' | awk '{ foo = $1 / 1024 / 1024 ; print foo "MB" }'

Not very robust, but it's easy to whip out for ad-hoc use.

David the H. · 10-21-2011, 01:57 AM

Here's a previous thread covering the same subject:

http://www.linuxquestions.org/questi...gb-etc-597921/

Edit: And here's another version I just found here (#13):

Code:

awk '{ split( "KB MB GB" , v ); s=1; while( $1>1024 ){ $1/=1024; s++ } print int($1) v[s] }'

I fixed the "smart quotes" the page was using, and modified it slightly so that the output is in a more standardized format ("25MB", "19GB", etc). You'll have to modify the field it processes for your own output, of course.

David the H. · 10-21-2011, 04:15 AM

I rewrote the above into a script that will process the line given above, with the important part set up as a function at the top.

Code:

#!/usr/bin/awk -f

function readable( input,     v,s )
  {
	split( "KB MB GB TB" , v )
	if( input + 0.0 == input )   #confirms that the input is a number
	   {
		while( input > 1024 ) { input /= 1024 ; s++ }
		return sprintf( "%0.2f %s" , input , v[s] )
	   }
	else
	   {
		return input
	   }
  }

BEGIN{
	FS="[= ]+"
     }

{
	if ( $0 ~ /_bytes/ )
	   {
		print( "received_bytes=" readable($2) " transmitted_bytes=" readable($4) )
	   }
	else
	   {
		print
	   }
}

Note that one weakness of awk is that it processes fields, and discards the separators between them. This makes it hard to keep the output in the same format as the input. I had to rebuild the entire input line from scratch in the print function. It could be a bit cleaner if you don't require the equal signs:

Code:

{
	if ( $0 ~ /_bytes/ )
	   {
		$2 = readable($2)
		$4 = readable($4)
		print
	   }
	else
	   {
		print
	   }
}

By the way: to be pedantic, the prefixes for byte increments should really be KiB, MiB, etc.:

http://en.wikipedia.org/wiki/Binary_prefix

syg00 · 10-21-2011, 06:08 AM

Quote:

Originally Posted by David the H.

Note that one weakness of awk is that it processes fields, and discards the separators between them. This makes it hard to keep the output in the same format as the input. I had to rebuild the entire input line from scratch in the print function. It could be a bit cleaner if you don't require the equal signs:

Or maybe just use the (other) fields it generates, and simply insert the "=" ?.

Nice solution BTW.

David the H. · 10-21-2011, 06:15 AM

Yeah, of course I could do that. I even did at one point while I was working it out. But it seems to me that if you're dealing with fixed strings anyway, you might as well just put them directly into the script.

Xeratul · 10-21-2011, 11:01 AM

lovely solutions !!

wow

I will test, and will post back

So cool. Many thousand thansk

H_TeXMeX_H · 10-22-2011, 07:10 AM

Here's my take on it in bash and some awk:

Code:

#!/bin/sh

# make sure we have 2 arguments
if test $# != 2
then
  echo "Usage: $(basename $0) number multiple"
  echo 'number: 3546456567'
  echo 'multiple: b/k/m/g/t'
  exit 1
fi

case "$2" in
	b)
		multiple=0
	;;
	k)
		multiple=1
	;;
	m)
		multiple=2
	;;
	g)
		multiple=3
	;;
	t)
		multiple=4
	;;
	*)
		echo 'ERROR: input not sane'
		exit 1
esac

echo "$1" "$multiple" | awk '
BEGIN{
	multiple[0]="b";
	multiple[1]="k";
	multiple[2]="m";
	multiple[3]="g";
	multiple[4]="t";
}
{
	while ($1 < 1)
	{
		$1*=1024;
		$2--;
	}
	while ($1 >= 1024)
	{
		$1/=1024;
		$2++;
	}
}
END{
	print $1 " " multiple[$2]
}'

exit 0