[SOLVED] Small awk script: critiques sought

grail · 03-24-2010, 09:49 AM

Hey catkin

I am sure you are probably getting sick of me

But I had another crack at this ( and made some quite different changes I thought might interest you.

Also, I stripped yours out and threw it in a script to (as wasn't sure how to run yours as is).
I have attached the output from both yours and my script (only a few discrepancies as yours seemed
to handle remarks as blank lines) and also your script as i was running it (as I said this could be wrong
way to do it) and mine is below in case you were interested

Cheers again for the challenge (although I would love to see how someone like ghostdog would do it,
probably a couple of one-liners <hehe>)

Code:

#!/usr/bin/awk -f

BEGIN {
	FS="[ \t]*=[ \t]*"
	f = 1
	g = 1
	cnt = 0
	value_arr_cnt = 0
}

$0 !~ /{|}/ && $0 !~ FS{ next }

{
	gsub(/^[ \t]+|#.*$/,"", $1)
	gsub(/[ \t]+$/, "", $1)
	key_org = "'"$1"'"
	gsub(/[ \t]+/,"", $1)
	key = tolower($1)
}

$2 ~ /#/ && index($2, "\"") > index($2, "#"){ f = 0 }

f && $2 ~ /".*"/{

	split($2, value, "\"")
	for (c in value)value_arr_cnt++

	for (x in value){
		gsub(/\\\\/, "SAVE", value[x])

		if (value[x] ~ /\\$/)
			gsub(/\\/, "\"", value[x])

		if (x % 2 == 1){
			gsub(/^[ \t]+|[ \t]+$/, "", value[x])

			if (value[x] ~ /^#.*/)
				for (y = x; y <= value_arr_cnt; y++)
					delete value[y]
		}
	
		if (value[x] ~ /"/ && value[x+1] != "")
			value[x+1] = value[x] value[x+1]

		gsub(/\\+/, "", value[x])
		gsub("SAVE", "\\", value[x])
	}

	g = 0
	value_arr_cnt = 0
}

g{
	gsub(/[ \t\"\\]+|#.*$/,"",$2)

	value[1] = $2
}

{
	print "keyword_org="key_org
	print "keyword="key
	for (x in value){
		if ( value[x] != "\"" && value[x] != "")
			print "conf_values["cnt++"]='"value[x]"'"
	}

	delete value
	f = 1
	g = 1
}

catkin · 03-24-2010, 10:33 AM

Quote:

Originally Posted by grail

Hey catkin

I am sure you are probably getting sick of me

But I had another crack at this ( and made some quite different changes I thought might interest you.

Also, I stripped yours out and threw it in a script to (as wasn't sure how to run yours as is).
I have attached the output from both yours and my script (only a few discrepancies as yours seemed
to handle remarks as blank lines) and also your script as i was running it (as I said this could be wrong
way to do it) and mine is below in case you were interested

You have been busy, grail!

And you identified a bug in my code -- leading tabs and spaces are not stripped from keyword_org

Regards your code, its output looks OK. Ideally I would have an expected output file and diff the actual output against it but my code (as the bash function name suggests) parses a single line so I do not have such an expected output file.

For performance reasons, if I was starting over, I would write the awk to parse the whole file as yours does, setting keyword[i], value_1[i], value_2[i], ... value_n[i] and not setting anything for functionally empty lines, again as yours does.

For maintainability, I'd modify your code especially changing "f" and "g" for names that show their meaning/purpose and adding a few comments. It is amazing how even one's own code can be hard to understand a few years later; if somebody else has to understand it ...

I'd also modify it so it didn't break if quoted values include the string "SAVE". No one would ever use such a string ... or might they!?

Best

Charles