sed - multiline search/replace with wildcard troubles

Yalla-One · 12-28-2008, 04:52 AM

Hello,

I'm writing a script to upgrade GPLv2 to GPLv3 across multiple files with multiple types of comments.The idea is that it should replace regardless of the file being a Makefile (each line starting with #), a C++/h file (no prefix) or a troff file (each file starting with .\").

Here's what only works if there are no prefixes of # or .\" :

Code:

/Software Foundation/{
N
s/\(.*\)\n/\1 /
s/^\((# )|(.\" )\)*Software Foundation; either version 2, or (at your option) any later \((# )|(.\" )\)version/\1Software Foundation, either version 3 of the License, or (at your \
\1option) any later version/
}

What I do is first search for Software Foundation in order to know where to start, then to join the two lines across which the pattern is located, and then try to put the option comment-prefixes (# or .\") into optional* hold-patterns...

Can anyone please help me by a clue as to where I've gone wrong?

Thanks in advance!

-y1

Kenhelm · 12-28-2008, 01:33 PM

The following uses GNU 'sed' with basic regular expressions (as used by 'grep'), not extended regular expressions (as used by GNU 'sed -r' and 'egrep'). Your code seems to mix elements of both.

Code:

Your pattern
\((# )|(.\" )\)*
should be something like
\(# \|\.\\" \)\?

The literal brackets have been removed, then | . and \ escaped.
In GNU sed \? is the same as * but only matches zero or one times

\1 can be used to repeat the pattern on the left side of the s command.
There's no need to remove the \n created by the N command as it can be matched in the patterns.
The variables a,b,A,B,prefix are used here just to make the logic clearer.

Code:

a='Software Foundation; either version 2, or (at your option) any later'
b='version'
A='Software Foundation, either version 3 of the License, or (at your '
B='option) any later version'
prefix='# \|\.\\" '
sed '/Software Foundation/{
N
'"s/^\($prefix\)\?$a\n\1$b/\1$A\n\1$B/"'
}' file

# Software Foundation, either version 3 of the License, or (at your
# option) any later version
.\" Software Foundation, either version 3 of the License, or (at your
.\" option) any later version
Software Foundation, either version 3 of the License, or (at your
option) any later version

Yalla-One · 12-28-2008, 03:04 PM

Quote:

Originally Posted by Kenhelm

Code:

a='Software Foundation; either version 2, or (at your option) any later'
b='version'
A='Software Foundation, either version 3 of the License, or (at your '
B='option) any later version'
prefix='# \|\.\\" '
sed '/Software Foundation/{
N
'"s/^\($prefix\)\?$a\n\1$b/\1$A\n\1$B/"'
}' file

You make it look so simple :-)

Thanks much - that hit the spot! Much appreciated!

-y1

jschiwal · 12-28-2008, 03:18 PM

Are these files that you authored? You man not be able to change the license of source that you didn't write. It takes the consent of all the contributers to do that. Even Linus can't change the license of the Linux Kernel on his own.

IIRC, there was a clause added to allow upgrading the GPL, but not all GPL2 licenses have it.
Also, the license of a project is probably included during the make or autoconf process to avoid needing to enter it into each file manually. There may be a single source for many projects.

Yalla-One · 12-29-2008, 12:01 PM

Quote:

Originally Posted by jschiwal

Are these files that you authored? You man not be able to change the license of source that you didn't write. It takes the consent of all the contributers to do that. Even Linus can't change the license of the Linux Kernel on his own.

I am aware of this. The author of the package in question asked me (as a non-programmer) for assistanc in converting the old source files from GPLv2 to GPLv3 and has confirmed that the other stakeholders are on par with this. I'm simply troing to help with the actual text replacement before realizing that I was in a bit over my head :-)
For older programs, the gpl text is hard coded into the headers, not set by autoconf... This one was last modified a few years ago.