Perl Help

rhugga · 01-30-2013, 04:17 PM

Ok. I'm pulling my hair out. I know I've written code just like this years ago but my perl has grown rusty. Anyway, simple debug routine that takes 4 arguments - a string and 3 numeric flags.

I call this function and depending upon where I want the output to go I set the 3 flags

debug("WARNING: blah blah", 1, 0, 0);

Here is the function (and yes I define a function prototype for this):

Code:

sub debug($$$$) {

    if ($DEBUG != 1) { return; } # DEBUG is a global var 

    my $_mesg   = shift;
    my $_f1     = shift;    # STDOUT
    my $_f2     = shift;    # STDERR
    my $_f3     = shift;    # LOGFILE

    if ($_f1 == 1) {
        printf STDOUT "%s : %s\n", localtime(), $_mesg;
        return;
    }
    if ($_f2) {
        sleep 1; # STUB
    }
    if ($_f3) {
        sleep 1; # STUB
    }
    return;
}

Here is sample output:
55 : 12
56 : 12
58 : 12

Why is my message displaying as 12

I'm sure this is something stupid, or my lack of sleep but right now this eludes me.

And yes, I know there are hundreds of debug modules I can use but this is concise and simple for what I need this to do. Data:

umper and similar modules are overkill for what I want to do here.

Thx

kbp · 01-30-2013, 05:52 PM

Your call to localtime() is providing the first and second arguments to printf(), you're not seeing the message at all as it's too far down the argument list and is dropped. Try creating a string with the time you want first and passing that:

Code:

#!/usr/bin/perl

use strict;
use warnings;

my $DEBUG = 1;
my $today;

sub getDate {
	my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime time;
	$mon += 1;
	$year += 1900;
	$mday = sprintf("%02d", $mday);
	$mon = sprintf("%02d", $mon);
	$today = "$mday/$mon/$year";
}

sub debug {

    if ($DEBUG != 1) { return; } # DEBUG is a global var 

    my $_mesg   = shift;
    my $_f1     = shift;    # STDOUT
    my $_f2     = shift;    # STDERR
    my $_f3     = shift;    # LOGFILE

    if ($_f1 == 1) {
        printf STDOUT "%s : %s\n", $today, $_mesg;
        return;
    }
    if ($_f2) {
        sleep 1; # STUB
    }
    if ($_f3) {
        sleep 1; # STUB
    }
    return;
}

getDate();
debug('WARNING: blah blah', 1, 0, 0);

mina86 · 01-31-2013, 07:13 AM

Instead of crafting another getDate function, you can also use scalar as in:

Code:

printf STDOUT "%s : %s\n", scalar localtime, $_mesg;