Perl add numbers in 2nd field

twantrd · 10-19-2006, 03:20 AM

I think I'm close to my answer but I can't yet seem to find it. Anyhow, I have a file:

Code:

john 10
mary 20
jack 30

And I'm trying to add up the 2nd column. So, the answer should be 60. Below is my perl code:

Code:

#!/usr/bin/perl

open(FILE, "/tmp/file") or die "Argh!";
while (my $rec=<FILE>){
        chomp($rec);
        my($name,$num)=split(/ / , $rec);
        $num+=$num;
        }
print "$num";

I've tried so many ways but now I'm exhausted. Can anyone see what I'm doing wrong? If I put a print "$num"; inside the while loop, it's adding the same number twice. Hmph. Thanks again!

-twantrd

Tinkster · 10-19-2006, 03:34 AM

Your file has a new-line after the actual payload?

Cheers,
Tink

bigearsbilly · 10-19-2006, 04:03 AM

one liner:

Code:

billy> perl -pae '$t += $F[1];print "$t:" ' data_file
10:john 10
30:mary 20
60:jack 30

Or here's my version which I made for my use

Code:

#!/usr/bin/perl -ws

sub usage()
{
    print <<"EOF";

# tots up all numbers in a tabular file
# assumes first column is the number to
# be totalled unless specified with -col=n
#
# e.g. try: 'du -s * | total'
#
# or
#
# ls -l | total -col=5
EOF
    die "\n";
}

$h ||= undef;
usage if $h;

$col ||=1;
$col--;

while (<>) {

    chomp;

    next unless /./; # skip blanks
    $number = (split)[$col];
    $total += $number;
    print;
    print " ($number)\n";

}

spirit receiver · 10-19-2006, 07:38 AM

Quote:

Originally Posted by twantrd

Code:

        my($name,$num)=split(/ / , $rec);
        $num+=$num;

There are two reasons why this won't work. As for the first, replacing the first line of your script with the following will give you a hint:

Code:

#!/usr/bin/perl -w

"use strict;" will also complain about that.

Secondly, what do you think "$num+=$num" will do?

twantrd · 10-19-2006, 04:23 PM

Ahh, I see my problem.

Quote:

Secondly, what do you think "$num+=$num" will do?

It will display the number on each iteration by 2x. What I needed was to add another variable that held the number - $total+=$num;. That solved my problem.

However, I have one more question

. My file is:

Code:

john 10
mary 20
rick - 
jack 30

My perl code is:

Code:

#!/usr/bin/perl -w

use strict;
use warnings;

my $total=0;
my $num=0;
open(FILE, "/tmp/file") or die "BlAH!";
while (my $rec=<FILE>){
        chomp($rec);
        my($name,$num)=split(/ / , $rec);
                if ($num =~ /^\d+/){
                        $total+=$num;
                }
        }
print "$total\n";

The code prints out the correct sum. However, it gives me this warning:

Quote:

Use of uninitialized value in pattern match (m//) at ./test line 12, <FILE> line 6.

What gives? I already declared variable $num in the beginning. Thanks for guiding me in the right direction guys.

-twantrd

spirit receiver · 10-19-2006, 05:56 PM

Seems like your data file contains an empty line. The error won't appear otherwise, you could also use the following:

Code:

[...] if ( defined( $num ) && $num =~ /^\d+/){ [...]

Note that the initialization "my $num = 0" won't be visible from within the while loop because of "my ( $name, $num)". This will create a new local variable named $num.

twantrd · 10-19-2006, 08:26 PM

Ahh. Thank you, spirit!

-twantrd