iter around same tags in xml with awk

frambau · 02-09-2012, 06:13 AM

Hi,

I have and XML like this

<item>
<title>Jack win the news</title>
<link>http://nom/hot/jack+white</link>
<guid>http://nt/jack+white</guid>
<name>juan</name>
<surname>martinez</surname>
</item>
<item>
<title>Glad to roll..</title>
<link>http://ww=1050681776</link>
<guid>http://fa&id=1050681776</guid>
<name>paco</name>
<surname>perez</surname>
</item>
...
...
...

and i need write all tags title in a different file index like this

Jack win the news > try_1.out
Glad to roll.. > try_2.out
...
...
...

i have this (thanks grail)
awk 'BEGIN{RS = "[<>]"}{ORS = /title/?"\n":"|"}/item/,/\/item/{if(/^(title)$/ && getline) print} input.xml

and this output
Jack win the news
Glad to roll..

any help? the other question is put in the title tag, the file name that i wrote

TAHNKS FOR ALL

Cedrik · 02-09-2012, 07:10 AM

Code:

awk '/<title>/ { gsub(/<\/?title>/,""); print > "try_"(++i)".out"; }' input.xml

frambau · 02-09-2012, 07:15 AM

Thank you so much

frambau · 02-09-2012, 07:46 AM

please CEDRIK another question.

if I get an input parameter in my sh how I can put it as a constant to make it like this?

Jack win the news > parameter_1.out
Glad to roll.. > parameter_2.out

frambau · 02-09-2012, 07:59 AM

thanks i try this

H="paco_"
awk -v nombre=$H '/<title>/ { gsub(/<\/?title>/,""); print > (nombre)(++i)".out"; }' input.xml

and this is correct THANKS YOU VERY MUCH!!!!!

Cedrik · 02-09-2012, 08:56 AM

Nice to see you make progress

frambau · 02-10-2012, 01:28 AM

Cedrik,

Another quesion for my XML,

If I remove the tags in my xml, how I can copy the contents of tags in a csv file, and that one is a sequential name tag?

for example,
<item>
<title>Jack win the news</title>
<link>http://nom/hot/jack+white</link>
<guid>http://nt/jack+white</guid>
<name>juan</name>
<surname>martinez</surname>
</item>
<item>
<title>Glad to roll..</title>
<link>http://ww=1050681776</link>
<guid>http://fa&id=1050681776</guid>
<name>paco</name>
<surname>perez</surname>
</item>
...
...
...

my csv will be

Jack win the news|try_1|http://nt/jack+white|juan|martinez
Glad to roll..|try_2|http://fa&id=1050681776|paco|perez
...
...
...

I have this for extract the fields

awk 'BEGIN{RS = "[<>]"}{ORS = /surname/?"\n":"|"}/item/,/\/item/{if(/^(title|link|guid|name|surname)$/ && getline)print}' input.xml

but idon't know how i can replace the link tag...

Thanks for all

grail · 02-10-2012, 02:12 AM

Just take link out of current if and use an alternate one for it instead.

frambau · 02-10-2012, 02:50 AM

Yes Grail, but if I use this

awk 'BEGIN{RS = "[<>]"}{ORS = /surname/?"\n":"|"}/item/,/\/item/{if(/^(title|guid|name|surname)$/ && getline)print}' input.xml

I am printing (title|guid|name|surname)

how i can put a secuential name between title and guid?

I use your line of yesterday:
H="try_"
awk -v name=$H 'BEGIN{RS = "[<>]"}/item/,/\/item/{if(/^(title|link|guid)$/ && getline)out = sprintf("%s%s%s",out,$0,/link/?"\n":"|");if(/\/item/){print (nombre)out x++;out=""}}' input.xml

Jack win the news|http://nom/hot/jack+white|http://nt/jack+white|try_0
Glad to roll..|http://ww=1050681776|http://fa&id=1050681776|try_1

I need this,

Jack win the news|try_0|http://nt/jack+white
Glad to roll..|try_1|http://fa&id=1050681776

Thanks again

Nominal Animal · 02-10-2012, 03:24 AM

How about

Code:

awk -v prefix="try_" '
    BEGIN {
        RS = "[\t\n\v\f\r ]*[<]"
        FS = "[>][\t\n\v\f\r ]*"
        id = 0
    }

    ($1 == "item" || $1 ~ /^item[\t\n\v\f\r ]/) {
        split("", field)
        id++
        next
    }

    ($1 ~ /^[A-Za-z]/) {
        name = $1
        sub(/[\t\n\v\f\r ]*$/, "", name)
        field[name] = $2
        next
    }

    ($1 == "/item") {
        printf("%s%d|%s|%s|%s|%s|\n",
               field["title"],
               prefix, id,
               field["guid"],
               field["name"],
               field["surname"])
    }
        
' input-file > output-file

The BEGIN rule sets the record separator to a beginning of a tag (plus any trailing whitespace prior to the <), and the field separator to > (plus any leading whitespace from the content). This means each tag, including its attributes, will be $1, and its immediate contents in $2.

The second rule clears the field array for a new item, and increases the id (sequence number). The second half of the rule pattern matches the case where the item tag has attributes; you can safely omit it if your input does not use attributes.

The third rule applies to all records where the first field starts with a letter -- i.e., to all start tags (except item, which matches the second rule, and the next tells awk to skip to the next record without applying further rules). It saves the immediate content of all start tags to the field associative array (keyed by the start tag name).

In your case the third rule contents could just be field[$1]=$2 but I wanted to point out that if you have attributes, they're included in $1. That is why I only use the name of the tag (removing all the attributes) as the key in the associative array.

The fourth rule applies to item end tag, and emits the desired pipe-separated record, using the associative array to recall the contents of each element.

Note that this scheme will only work for flat XML data without any comments or CDATA sections. Within each item element, it is assumed each element contains only text, not any sub-elements. If an element occurs twice, only the last one is recalled. So, it is very limited, but it might work for you.

Hope this helps,

frambau · 02-10-2012, 03:36 AM

THANKS NOMINAL.

I'm trying various things, about it and trying this:

awk '/<title>/ { gsub(/<\/?title>/,""); print > "try_"(++i)".out"; }' input.xml

the sentence can only create output files thousand and I need some more.

How i can create more?

---------- Post added 02-10-12 at 04:36 AM ----------

thanks for all to all!!!!

frambau · 02-10-2012, 04:18 AM

I'm trying tu use close after "try_"(++i)".out"

like this

awk '/<title>/ { gsub(/<\/?title>/,""); print > "try_"(++i)".out" close((name)(i)".out") }' input.xml

but it generate files with this name

try__2.out-1
try__1.out-1

Any help?

THANKS

Nominal Animal · 02-10-2012, 04:56 AM

Use

Code:

   file = sprintf("%s%06d.out", "try_", ++id)

to generate a good file name first. The %06d emits the number as 000001, 000002, and so on.

Then, output to the file, e.g.

Code:

   print > file

Note that you can use multiple print or printf() commands to print to the file. The first one will clear the previous file contents, but all other print and printf() commands will append to it.

Finally, close the file using

Code:

   close(file)

You need to close the file, because otherwise awk will run out of file descriptors. Unlike e.g. Bash, it does not automatically close files you've written to; you must explicitly close the file to tell awk you're done with it. (The same applies to reading from files using < redirection, too.)

You can run getconf OPEN_MAX to see the maximum number of open file descriptors per process. In Linux, the default is 1024, but at least three are used for standard input, output, and error. Thus, you usually can keep 1021 files open for reading or writing at the same time. (Awk might need one or more for itself, for e.g. reading the script file, though.)

frambau · 02-10-2012, 05:21 AM

thnaks Nominal i'm going to try this

awk -v name=$H 'BEGIN {RS = "[<>]"}{ORS = /description/?"\n":"|"}/item/,/\/item/{if(/^(description)$/ && getline)out = $0; file = sprintf("%s%d.out",name,++i); print out > file;close(file)}' input.xml

because the particularities of my program.

but for two items, this sentence print a lot of .out files why?????

THANKS AGAIN FOR ALL

frambau · 02-10-2012, 05:24 AM

I realy need to extract all the tag content in a xml to a diferent secuentials files. One for each tags