Delete next line in sed

Yalla-One · 01-02-2009, 01:24 PM

So I've stumbled across another challenge on my adventure towards full sed understanding.

Let's say I want to delete all lines ending with "The END" that follow a line ending in "FOLLOW ME"

Should it not be possible to:

Code:

/FOLLOW ME$/{
N
s/\(.*\)\n.*The END/\1/
}

clearly not, since it won't work...

So then I tought, maybe it's possible to just give a delete command /d , but then I couldn't make it test for the end of the line....

Any takers? Thanks in advance!

-y1

taylor_venable · 01-02-2009, 02:22 PM

I have to say, I learned a lot about sed by solving this one!

Code:

/FOLLOW ME$/ {
    p
    c\

    n
    bx
}

p
d

:x
{
    /The END$/ ! p
    c\

    n
    bx
}

It's kind of a cheap move since sed is stateless, but what we basically do is find the "FOLLOW ME" then enter into a loop constantly clearing and replacing the contents of the pattern space with the next line. This only goes through as many cycles as there are lines before the "FOLLOW ME", then after that it loops within the current cycle gathering up lines until EOF.

Note that this would be much more clearly implemented in awk, but since you asked for sed...

pixellany · 01-02-2009, 04:36 PM

Quote:

Originally Posted by taylor_venable

I have to say, I learned a lot about sed by solving this one!

Me too....

Code:

sed '/follow me/,${/the end$/d}'

This works from the first instance of "follow me" to the end of the file

pixellany · 01-02-2009, 04:43 PM

Just realized a semantic ambiguity.....my solution starts on the first instance of "follow me", and then deletes all instances of "the end" at the end of subsequent lines.

If you meant delete lines ending in "the end" ONLY if the immediately follow one with "follow me", then my solution does not work

taylor_venable · 01-02-2009, 07:36 PM

Ha ha! The simple solution completely evaded me! At least the incredibly over-engineered solution provides a starting point for doing more complex things like only deleting lines which appear immediately after "FOLLOW ME" but I must confess I wasn't considering this when I spent fifteen minutes writing it.

I have to say I was very pleased when I found out you can use labels and branches in sed. Crazy.

Edit: Ooh, I just tested my complicated solution with GNU sed and it does... basically nothing. Upon further investigation, it seems that GNU sed never branches down to the label after reading "FOLLOW ME"; a new cycle starts immediately after the n command. The posted solution works correctly with BSD sed (or at least the one in OpenBSD).

makyo · 01-03-2009, 10:12 AM

Hi.

Posts that include a sample data set and desired output (inside CODE tags) help to avoid ambiguity (but may also avoid the flights of serendipitous learning while chasing the ambiguity

) ... cheers, makyo

pixellany · 01-03-2009, 07:26 PM

Another solution, assuming that we want to delete only the line immediately after the one with "follow me", if said line has "the end" at the end:

Code:

sed '/follow me/{n; /the end$/d}'

Yalla-One · 01-04-2009, 12:37 PM

Quote:

Originally Posted by pixellany

Another solution, assuming that we want to delete only the line immediately after the one with "follow me", if said line has "the end" at the end:

Code:

sed '/follow me/{n; /the end$/d}'

Perfect! I didn't realize I could nest the "search items" within a begin. This hit the spot perfectly.

Thanks much to everyone who came with ideas - much appreciated!

-y1

Sergei Steshenko · 01-04-2009, 03:29 PM

What about http://www.unixguide.net/unix/perl_oneliners.shtml ->

Code:

# delete all but lines beween START and END
   perl -i.old -ne 'print unless /^START$/ .. /^END$/' foo.txt

- this, of course, is not 'sed', but do you really care ?

pixellany · 01-04-2009, 04:00 PM

Quote:

Originally Posted by pixellany

Another solution, assuming that we want to delete only the line immediately after the one with "follow me", if said line has "the end" at the end:

Code:

sed '/follow me/{n; /the end$/d}'

I found a flaw in this:

If you have a line with "follow me", and then the next line does NOT contain "the end", it fails on the next cycle.

This appears to fix the issue, but I'm not done testing:

Code:

sed ':here /follow me/{n; /the end$/d; b here}'