[SOLVED] Problem ternary (?:) in awk

Trd300 · 10-04-2012, 10:02 PM

Hi Linux Gurus !

My input looks like:

Code:

first_A|last_B|bio|score_100
first_A|last_B|math|score_50
first_C|last_D|bio|score_70
first_C|last_D|phys|score_35
first_C|last_D|math|score_55

I would need to append on a same line all the information related to the same first and second fields:

Code:

first_A|last_B|bio|score_100|math|score_50
first_C|last_D|bio|score_70|phys|score_35|math|score_55

For that I tried to use the ternary ( ?: ) as follow:

Code:

BEGIN{FS=OFS="|"}

{
    array[$1$2] = (array[$1$2] ? array[$1$2] : $1 FS $2) FS $3 FS $4
    print array[$1$2]
}

But I get all the intermediate steps until I reach the output I want:

Code:

first_A|last_B|bio|score_100
first_A|last_B|bio|score_100|math|score_50
first_C|last_D|bio|score_70
first_C|last_D|bio|score_70|phys|score_35
first_C|last_D|bio|score_70|phys|score_35|math|score_55

I tried to empty the variable first but it cannot save the previous field and I get the same as input:

Code:

BEGIN{FS=OFS="|"}

{
    f1 = ""  
    f1 = (array[$1$2] ? array[$1$2] : $1 FS $2) FS $3 FS $4
    $0 = f1
    print $0
}

Does someone see what I am doing wrong?

druuna · 10-05-2012, 02:44 AM

You need an END part to print the content of the array.

Instead of:

Code:

BEGIN{FS=OFS="|"}

{
    array[$1$2] = (array[$1$2] ? array[$1$2] : $1 FS $2) FS $3 FS $4
    print array[$1$2]
}

try

Code:

BEGIN { FS=OFS="|" }
{ 
  array[$1$2] = (array[$1$2] ? array[$1$2] : $1 FS $2) FS $3 FS $4
}
END { for (var in array) print array[var] }

You cannot predict the order in which the array is printed, you might need to sort the output (can probably done with awk, but piping it to sort might be easier):

Code:

#!/bin/bash

awk 'BEGIN { FS=OFS="|" }
{
  array[$1$2] = (array[$1$2] ? array[$1$2] : $1 FS $2) FS $3 FS $4
}
END { for (var in array) print array[var] }
' infile | \
sort

Trd300 · 10-06-2012, 07:41 PM

Thanks druuna !